Regeln für Buchungsvorschläge

Regeln zur Aufteilung von Zins und Tilgung (Primanota Feldzuweisung Umsatz)

Es sind für Tilgung und Zinsen jeweils separate Regeln aufzustellen. Im Feld Umsatz muss dabei eine Formel eingetragen werden. Wie diese Formel auszusehen hat, zeigen die nachfolgenden Beispiele.

Beispiele für Sparkassen

1. Beispiel Text-1:

Rechnung                   Darl.-Leistung 1234567899  Für 01.09.2024 - 30.09.2024Saldo:           48.459,91-Tilgung             781,65 Zinsen              187,01 20240930-AB123-00012345678

2. Beispiel Text-1 mit UST auf Darlehenszinsen:

Rechnung                   Darl.-Leistung 1234567890  Für 01.07.2024 - 30.09.2024Saldo:          807.475,00-Tilgung          14.936,00 Zinsen            4.007,87 20240930-NI123-00012345678 UST:             761,50 EUR

Formel für Tilgung:

=0-Value(Replace(".";"";(Teil([Text-1];Find("Tilgung";[Text-1])+7;19))))

Formel für Zinsen ohne USt:

= 0-Value(Replace(".";"";(Teil([Text-1];Find("Zinsen";[Text-1])+6;20))))

Formel für Zinsen mit USt:

=0-Runden(Value(Replace(".";"";(Teil([Text-1];Find("Zinsen";[Text-1])+6;20))))*1,19)

Erläuterung der Formeln

Zunächst wird nach „Tilgung“ bzw. „Zinsen“ gesucht, das Ergebnis ist die Position der Fundstelle des Suchtextes, z.B. Find(„Tilgung“; [Text-1]).

Unabhängig von der Höhe des Tilgungs- bzw. Zinsbetrags ist hier die Länge immer 26 Zeichen, davon sind 7 Zeichen für den Text „Tilgung“ bzw. 6 Zeichen für Text „Zinsen“. Um den Teil mit dem Tilgungsbetrag aus dem Text auszuschneiden, wird ausgehend von der gefundenen Position 7 Zeichen hinzuaddiert und dann die folgenden 19 Zeichen herauskopiert bzw. 6 und 20 Zeichen bei Zinsen mit dem Befehl Teil oder Copy, z.B. Teil([Text-1];Find("Tilgung";[Text-1])+7;19)) Um diesen Text in eine Zahl umzuwandeln, wird der Befehl Value/Wert genutzt, damit dies funktioniert, muss aber vorher der Tausenderpunkt entfernt werden mit Replace oder Wechseln: Replace(".";""; Text)

Wenn auf die Darlehenszinsen Umsatzsteuer erhoben wird und man möchte den Bruttobetrag buchen mit USt-Schlüssel, dann ist der Betrag bei 19 % USt mit 1,19 zu multiplizieren und dann auf 2 Nachkommastellen zu Runden mit dem Befehl Round oder Runden.

Schließlich soll der Betrag negativ sein, deshalb wird die Zahl von Null abgezogen und die Formel beginnt mit „=0-“.

Beispiele für Volksbanken

1. Beispiel Text-1:

IBAN DE31210900070000020000RECHN.ZINS 122,52 TILG./ENTG. 807,48 TILGUNG PER 30.09.2024

2. Beispiel Text-1:

IBAN DE31210900070000020000RECHN.ZINS 29,53 TILG./ENTG. 518,53 TILGUNG PER 30.09.2024 NEUER SALDO 18.634,48S

3. Beispiel Text-1:

IBAN DE31210900070000020000RECHN.ZINS 184,72 TILG./ENTG. 2.745,03 TILGUNG PER 30.09.2024 MREF: 5550777022D12345670001239999 CRED: DE70ZZZ00000012345

Formel für Tilgung:

=0-Value(Replace(".";"";(Teil([Text-1];Find("TILG.";[Text-1])+11;Find("TILGUNG";[Text-1])-(Find("TILG.";[Text-1])+11)))))

Formel für Zinsen:

=0-Value(Replace(".";"";(Teil([Text-1];Find("ZINS";[Text-1])+4;Find("TILG.";[Text-1])-(Find("ZINS";[Text-1])+4)))))

Erläuterung der Formeln

Zunächst wird nach „ZINS“ bzw. „TILG.“ gesucht, das Ergebnis ist die Startposition der Fundstelle des Suchtextes, z.B. Find(„ZINS“; [Text-1]).

Da nach dem Text „ZINS“ (Zeichenlänge=4) der Betrag steht, wird zur Startposition 4 hinzuaddiert: Find("ZINS“;[Text-1])+4, bei „TILG./ENTG.“ entsprechend 11.

Hier ist die Länge des Textes mit dem Betrag unterschiedlich lang, daher muss die Anzahl von Zeichen ermittelt werden, dafür sucht man den Endpunkt, d.h. bei Zinsen sucht man den Text „TILG.“ und bei der der Tilgung sucht man den Text „TILGUNG“ und subtrahiert von dieser Position die Startposition zuzüglich der Textlänge von „ZINS“, also 4 bzw. „TILG./ENTG“, also 11 Zeichen. Mit dem Befehl Teil oder Copy kann nun der Textteil ausgeschnitten werden mit dem jeweiligen Betrag: Teil([Text-1]; Startposition; Anzahl Zeichen)

Um diesen Text in eine Zahl umzuwandeln, wird der Befehl Value oder Wert genutzt, damit dies funktioniert, muss aber vorher der Tausenderpunkt entfernt werden mit Replace oder Wechseln: Replace(".";""; Text)

Schließlich soll der Betrag negativ sein, deshalb wird die Zahl von Null abgezogen und die Formel beginnt mit „=0-“.

Beispiele für OLB

1. Beispiel Text-1:

DARL-ABR 09/2024                   ZINS       484,01- ENTGELT    0,00+TILG      7875,99-

2. Beispiel Text-1:

DARL-ABR 09/2024 REST   1040000,00-ZINS      3352,80- ENTGELT    0,00+TILG     17000,00- UST      637,03-

Formel für Tilgung:

=0-Value(Teil([Text-1];Find("TILG";[Text-1])+4;13))

Formel für Zinsen ohne USt:

=0-Value(Teil([Text-1];Find("ZINS";[Text-1])+4;13))

Formel für Zinsen mit USt:

=0-Runden(Value(Teil([Text-1];Find("ZINS";[Text-1])+4;13))*1,19)

Erläuterung der Formeln

Zunächst wird nach „TILG“ bzw. „ZINS“ gesucht, das Ergebnis ist die Position der Fundstelle des Suchtextes, z.B. Find(„TILG“; [Text-1]).

Unabhängig von der Höhe des Tilgungs- bzw. Zinsbetrags ist hier die Länge immer 17 Zeichen , davon sind 4 Zeichen für den Text „TILG“ bzw. „ZINS“. Um den Teil mit dem Tilgungsbetrag aus dem Text auszuschneiden, wird ausgehend von der gefundenen Position 4 Zeichen hinzuaddiert und dann die folgenden 13 Zeichen herauskopiert mit dem Befehl Copy oder Teil (Text; Startposition; Anzahl Zeichen), z.B. Teil([Text-1];Find("TILG";[Text-1])+4;13)). Um diesen Text in eine Zahl umzuwandeln, wird der Befehl Value oder Wert genutzt.

Wenn auf die Darlehenszinsen Umsatzsteuer erhoben wird und man möchte den Bruttobetrag buchen mit USt-Schlüssel, dann ist der Betrag bei 19 % USt mit 1,19 zu multiplizieren und dann auf 2 Nachkommastellen zu Runden mit dem Befehl Round oder Runden.

Beispiele für Unicredit/Hypovereinsbank

1. Beispiel Text-1:

Rechnung Darl.-Leistung 6123456789 Tilgung 1.135,00 Zinsen 926,13

2. Beispiel Text-1:

Rechnung Darl.-Leistung 6112345678 Tilgung 12.800,00 Zinsen 1.894,38

Formel für Tilgung:

=0-Value(Replace(".";"";(Teil([Text-1];Find("Tilgung";[Text-1])+7;Find("Zinsen";[Text-1])-(Find("Tilgung";[Text-1])+7)))))

Formel für Zinsen

=0-Value(Replace(".";"";(Teil([Text-1];Find("Zinsen";[Text-1])+6))))

Erläuterung der Formeln

Zunächst wird nach „Zinsen“ bzw. „Tilgung“ gesucht, das Ergebnis ist die Startposition der Fundstelle des Suchtextes, z.B. Find(„Zinsen“; [Text-1]). Da nach dem Text „Zinsen“ (Zeichenlänge=6) der Betrag steht, wird zur Startposition 6 hinzuaddiert: Find("Zinsen“;[Text-1])+6, bei „Tilgung“ entsprechend 7.

Die Länge des Textes mit dem Betrag ist unterschiedlich. Dies ist bei den Zinsen kein Problem, da der Betrag am Textende steht. Beim Tilgungsbetrag muss die Anzahl der Zeichen ermittelt werden, dafür sucht man den Endpunkt, in diesem Fall beginnt dort der Text „Zinsen“ und subtrahiert von dieser Position die Startposition zuzüglich der Textlänge von „Tilgung“, also 7 Zeichen., d.h. Anzahl der Zeichen ermittelt sich folgendermaßen: Find("Zinsen";[Text-1])-(Find("Tilgung";[Text-1])+7)

Mit dem Befehl Teil oder Copy kann nun der Textteil ausgeschnitten werden mit dem jeweiligen Betrag: Teil([Text-1]; Startposition; Anzahl Zeichen).

Um diesen Text in eine Zahl umzuwandeln, wird der Befehl Value oder Wert genutzt, damit dies funktioniert, muss aber vorher der Tausenderpunkt entfernt werden mit Replace oder Wechseln: Replace(".";""; Text)

Schließlich soll der Betrag negativ sein, deshalb wird die Zahl von Null abgezogen und die Formel beginnt mit „=0-“.